0 SYS35208:CLR:SYS32952:GOTO9000
1 INPUT#15,A$,Z$,A$,A$:IFZ$="OK"THENRETURN
2 PRINTZ$:CLOSE8,15:GOTO260
3 SYS35215:A=PEEK(2):SYS49712:RETURN
4 SYS34011:GOTO6150
6 SYS34011:GETA$:IFA$=""THEN6
7 SYS49712:RETURN
8 SYS34011:SYS34764:SYS49712:RETURN
9 KK$=RIGHT$(STR$(Z),LEN(STR$(Z))-1):RETURN
10 SYS34743:RETURN
12 SYS34725:RETURN
13 SYS34642:GOSUB6
14 IFA$<>"Y"ANDA$<>"N"THENGOSUB6:GOTO14
15 RETURN
19 SYS34616:RETURN
21 GOSUB25:SYS35317:GOTO8
23 SYS35331:PRINTC$;:SYS34584:RETURN
25 IFPEEK(1024)<>85THENGOSUB1950:SYS34536:RETURN
26 SYS34087:RETURN
29 SYS34557:RETURN
31 KK$=KK$+"                  ":KK$=LEFT$(KK$,18):PRINTKK$:SYS34011:RETURN
40 SYS35345:RETURN
42 PRINT" LETZTER ";CP%;"CUP SIEGER WAREN-:":FORN=1TOCP%
43 PRINT" CUP ";:A$="  "+STR$(CP%+1-N):PRINTRIGHT$(A$,4)"    "CW$(N):NEXT:RETURN
50 KL=LEN(A$):FORZ=1TOKL:IFMID$(A$,Z,1)="0"THENGOSUB52
51 NEXTZ:RETURN
52 A1$=LEFT$(A$,Z-1)+"O":A2$=RIGHT$(A$,KL-Z):A$=A1$+A2$:RETURN
60 SYS35411:RETURN
61 SYS35425:RETURN
62 SYS35444:RETURN
63 SYS34764:SYS49712:RETURN
69 IFZ>9.99THEN73
70 KK$=STR$(Z+10.001):KK$=RIGHT$(KK$,LEN(KK$)-2):KK$=LEFT$(KK$,LEN(KK$)-1)
71 RETURN
72 IFZ>=1000000THENKK$=STR$(INT(Z/10000)/100)+" MIL.":RETURN
73 KK$=STR$(Z+.001):KK$=RIGHT$(KK$,LEN(KK$)-1):KK$=LEFT$(KK$,LEN(KK$)-1):RETURN
79 IFZ>99999.99THEN72
80 IFZ<0THENKK$=STR$(Z)+".OO":RETURN
81 KK$=STR$(Z+100000.001):KK$=RIGHT$(KK$,LEN(KK$)-2):KK$=LEFT$(KK$,LEN(KK$)-1)
82 RETURN
98 SYS34011:FORK7=1TO2000:NEXTK7:A=FRE(A):RETURN
99 SYS34011:FORK7=1TO999:NEXTK7:A=FRE(A):RETURN
100 W=W+1:GOSUB6000:SYS50176:FORR=1TO7:GOSUB1000:GOSUB1300
160 SYS35520:GOSUB13:GOSUB6250:PRINT"[147]":POKE700,9:IFA$="N"THENPOKE700,0
170 GOSUB500:GOSUB2500:GOSUB3000:IFR<5THENGOSUB3500
200 NEXTR:GOSUB5500:SYS35610:FORN=1TO8:P(N,0)=P(N,0)+500:NEXT
216 PRINT" DU SPIELTEST"W"WOCHE(N)  ":PRINT" WILLST DU AUFHOEREN ?        "
217 GOSUB13:IFA$="N"THENGOSUB6250:GOTO100
220 GOSUB40:PRINT" BIST DU DIR SICHER AUFZUHOEREN      ?":GOSUB13
225 IFA$="Y"THENGOSUB6250:GOTO250
230 PRINT" DER BUCHMACHER LACHT NICHT MEHR   !!!":GOSUB99:GOSUB6250:GOTO100
250 PRINT"[147] WOLLEN SIE DAS SPIEL ABSAVEN       ?":GOSUB13:IFA$="N"THEN260
255 GOSUB9800
260 PRINT" DANKE FUER SPIELEN  .":PRINT" BITTE SCHALTEN SIE COMPUTER AUS     ."
265 GOTO265
500 SYS35604:FORN=1TO8:PRINTR$(N)Z$(N):NEXT
510 N=(R%(P%(1),4)-2600)/100:A$=STR$(N):A$=RIGHT$(A$,LEN(A$)-1):PRINT"0"A$"00"
520 PRINTW:PRINTR:FORN=1TO8:PRINTP%(N):NEXTN:A$=STR$(TR):N=LEN(A$)
525 IFN=3THENA$=A$+".":N=4
530 A$=A$+"00":N=N+2:A$=RIGHT$(A$,N-1):PRINTLEFT$(A$,5):SYS35607
535 IFR=7THENGOSUB4000
540 RETURN
800 FORN=1TO8:IFP(N,2)=0THEN815
805 Z=N:GOSUB9:B$(N)="  "+KK$+" [146] [158]"+P$(N):Z=P(N,0):GOSUB79
810 B$(N)=B$(N)+" $"+KK$:A$=B$(N):GOSUB50:B$(N)=A$
815 NEXTN:RETURN
900 FORN=1TO8:A$="[146] [158] "+CHR$(P%(N)+48)+"  "+R$(P%(N))+" [154] "+Z$(P%(N))+" [146]"
905 A$=A$+STR$(R%(P%(N),4)/100):Y$(N)=A$:NEXT
910 Y1$=" [158] "+CHR$(P%(1)+48)+"  "+R$(P%(1))+" [154]  SIEG [146]  $":Z=WW:GOSUB69
915 Y1$=Y1$+KK$:FORK=1TO3
920 I$(K)=" [158] "+CHR$(P%(K)+48)+"  "+R$(P%(K))+" [154] PLATZ [146]  $":Z=DP(K)
925 GOSUB69:I$(K)=I$(K)+KK$:NEXTK:Y2$="[146] ZWEIERWETTE FUER"+STR$(P%(1))+" UND"
930 Y2$=Y2$+STR$(P%(2))+" GIBT $":Z=DP(4):GOSUB69:Y2$=Y2$+KK$
935 Y3$="[146] DREIERWETTE FUER"+STR$(P%(1))+" "+STR$(P%(2))+" "+STR$(P%(3))
940 Y3$=Y3$+" GIBT $":Z=DP(5):GOSUB69:Y3$=Y3$+KK$
950 FORN=1TO4:B$(N)="[146] [158] "+P$(R%(P%(N),3))+" [146] $":Z=S(N):GOSUB9
955 B$(N)=B$(N)+KK$:NEXTN
960 FORN=1TO8:IFP(N,2)=0THEN975
965 C$(N)=" "+P$(N)+"[154]$":Z=P(N,1):GOSUB79:C$(N)=C$(N)+KK$+" [158]$":Z=P(N,0)
970 GOSUB79:C$(N)=C$(N)+KK$:A$=C$(N):GOSUB50:C$(N)=A$
975 NEXT:FORN=1TO4:A$=B$(N):GOSUB50:B$(N)=A$:NEXT:A$=Y1$:GOSUB50:Y1$=A$
998 A$=Y2$:GOSUB50:Y2$=A$:A$=Y3$:GOSUB50:Y3$=A$:FORN=1TO3:A$=I$(N):GOSUB50
999 I$(N)=A$:NEXT:Z=FRE(Z):SYS34545:RETURN
1000 SYS35613:SYS49705:B5=2790+INT(RND(0)*10):B4=2790+INT(RND(0)*20)
1010 R$(0)=RN$(R):B3=2780+INT(RND(0)*20)
1023 FORN=1TO8:A=N%(R,N):R%(N,0)=A:R%(N,3)=D%(A,9):R%(N,5)=D%(A,3)
1026 R%(N,6)=D%(A,1):R%(N,7)=D%(A,2):R%(N,8)=D%(A,4):R%(N,9)=D%(A,10)
1030 R%(N,10)=D%(A,5):R%(N,11)=D%(A,6):R%(N,12)=D%(A,7):T=2*(100-R%(N,11))
1040 R%(N,13)=R%(N,10)+T:T=R%(N,12)/20:R%(N,14)=INT((T-INT(T))*20)
1050 R%(N,15)=INT(T)
1051 Z=R%(N,13):T=0:IFZ<B5+80THENT=1:IFZ<B5+40THENT=2:IFZ<B5+20THENT=3
1052 IFZ<B5+10THENT=4:IFZ<B5+5THENT=5:IFZ<B5THENT=6
1053 R%(N,19)=T:T=0:IFZ<B4+100THENT=1:IFZ<B4+80THENT=2:IFZ<B4+60THENT=3
1054 IFZ<B4+40THENT=4:IFZ<B4+20THENT=5:IFZ<B4THENT=6
1055 R%(N,18)=T:T=0:IFZ<B3+210THENT=1:IFZ<B3+160THENT=2:IFZ<B3+110THENT=3
1056 IFZ<B3+70THENT=4:IFZ<B3+40THENT=5:IFZ<B3THENT=6
1057 R%(N,17)=T:R$(N)=D$(A,0):NEXT:FORN=1TO8:FORT=17TO19
1060 IFR%(N,T)<BPTHENR%(N,T)=BP
1065 NEXTT,N
1070 FORN=1TO8:POKE40735+N,R%(N,14):POKE40743+N,R%(N,15)
1080 POKE40759+N,R%(N,17):POKE40767+N,R%(N,18):POKE40775+N,R%(N,19):NEXT
1090 SYS33074
1100 FORN=1TO8:R%(N,20)=PEEK(40791+N):R%(N,2)=PEEK(40799+N):X=INT(RND(0)*6)
1110 R%(N,15)=R%(N,15)+X:POKE40743+N,R%(N,15):R%(N,16)=INT(RND(0)*8)
1120 POKE40751+N,R%(N,16):NEXT:SYS33329
1140 FORN=1TO8:R%(N,1)=PEEK(40799+N):R%(N,4)=PEEK(40807+N)
1150 IFR%(N,20)=0THENR%(N,20)=1
1151 G=R%(N,20):IFR%(N,2)=0THENR%(N,2)=1
1152 IFG>83THENZ$(N)=" *1/1O":Z(N)=.1:GOTO1184
1153 IFG>66THENZ$(N)=" *2/1O":Z(N)=.2:GOTO1184
1154 IFG>55THENZ$(N)=" *5/1O":Z(N)=.5:GOTO1184
1155 IFG>50THENZ$(N)=" *8/1O":Z(N)=.8:GOTO1184
1156 IFG>45THENZ$(N)="  1/1 ":Z(N)=1:GOTO1184
1157 IFG>40THENZ$(N)=" 12/1O":Z(N)=1.2:GOTO1184
1158 IFG>35THENZ$(N)=" 15/1O":Z(N)=1.5:GOTO1184
1159 IFG>33THENZ$(N)=" 18/1O":Z(N)=1.8:GOTO1184
1160 IFG>28THENZ$(N)="  2/1 ":Z(N)=2:GOTO1184
1161 IFG>25THENZ$(N)=" 25/1O":Z(N)=2.5:GOTO1184
1162 IFG>22THENZ$(N)="  3/1 ":Z(N)=3:GOTO1184
1163 IFG>20THENZ$(N)=" 35/1O":Z(N)=3.5:GOTO1184
1164 IFG>16THENZ$(N)="  4/1 ":Z(N)=4:GOTO1184
1165 IFG>14THENZ$(N)="  5/1 ":Z(N)=5:GOTO1184
1166 IFG>12THENZ$(N)="  6/1 ":Z(N)=6:GOTO1184
1167 IFG=12THENZ$(N)="  7/1 ":Z(N)=7:GOTO1184
1168 IFG>9THENZ$(N)="  8/1 ":Z(N)=8:GOTO1184
1169 IFG=9THENZ$(N)=" 1O/1 ":Z(N)=10:GOTO1184
1170 IFG=8THENZ$(N)=" 12/1 ":Z(N)=12:GOTO1184
1171 IFG=7THENZ$(N)=" 15/1 ":Z(N)=15:GOTO1184
1172 IFG=6THENZ$(N)=" 18/1 ":Z(N)=18:GOTO1184
1173 IFG=5THENZ$(N)=" 2O/1 ":Z(N)=20:GOTO1184
1174 IFG=4THENZ$(N)=" 25/1 ":Z(N)=25:GOTO1184
1175 IFG=3THENZ$(N)=" 33/1 ":Z(N)=33:GOTO1184
1176 IFG=2THENZ$(N)=" 5O/1 ":Z(N)=50:GOTO1184
1177 G=R%(N,2):IFG=1THENZ$(N)="5OO/1 ":Z(N)=500:GOTO1184
1178 IFG<4THENZ$(N)="2OO/1 ":Z(N)=200:GOTO1184
1179 IFG<7THENZ$(N)="1OO/1 ":Z(N)=100:GOTO1184
1180 IFG<11THENZ$(N)=" 75/1 ":Z(N)=75:GOTO1184
1181 Z$(N)=" 65/1 ":Z(N)=65
1184 T=R%(N,1):P%(T)=N:NEXT:T=R%(P%(1),13):LK=R%(P%(1),15)-INT(R%(P%(1),12)/20)
1185 JM=R%(P%(1),12)-50
1190 LK=LK+R%(P%(1),16):LK=LK*10:BT=T+(120-LK)
1195 FORN=1TO8:R%(N,4)=BT+246-R%(N,4)-JM:NEXT
1200 WW=.5+(Z(P%(1))/2):FORA=1TO3:K1=100/R%(P%(A),2):K1=K1*50
1210 K1=INT(K1/5)*5:DP(A)=K1/100:NEXTA
1213 A=(R%(P%(1),20)+R%(P%(2),20))/100:B=(R%(P%(1),2)/133)*(R%(P%(2),2)/133)
1215 A=A*B:A=1/A:B=(A*.5)+.5:A=INT(B*20):DP(4)=A/20:A=1:DP(5)=DP(4)*2
1217 DP(5)=DP(5)*(DP(3)*2)
1220 A=R%(P%(1),20):B=R%(P%(2),20):C=A+B:DP(5)=DP(5)*(C/A):A=DP(5)/2
1225 A=INT(A*20):DP(5)=A/20
1226 CN=1:HC=500:FORN=1TO8:IFZ(N)<HCTHENHC=Z(N):CN=N
1227 NEXT:POKE49541,CN
1230 IFR=7THEN4500
1240 SYS50176:POKE53269,0:SYS33904:RETURN
1300 GOSUB1950:PRINT" WOLLEN SIE MEHR INFORMATIONEN  ?[154]":SYS34536:GOSUB13
1310 IFA$="N"THEN1500
1320 GOSUB25:PRINT"";:GOSUB1800
1322 GOSUB1325:GOSUB1450:SYS34536:SYS34764:SYS49712:GOTO1365
1325 POKE2,A:SYS36005:C$=CHR$(PEEK(2)):PRINTR$(A)" "Z$(A);:SYS36029:RETURN
1365 PRINTC$"[146]STARTS           : ";:Z=D%(R%(A,0),3):GOSUB9:GOSUB31
1366 PRINTC$"[146]SIEGE            : ";:Z=D%(R%(A,0),1):GOSUB9:GOSUB31
1367 PRINTC$"[146]2TER & 3TER      : ";:Z=D%(R%(A,0),2):GOSUB9:PRINTKK$"  "
1368 PRINTC$"[146]UNPLAZIERT       : ";:Z=D%(R%(A,0),3)-D%(R%(A,0),1)
1369 Z=Z-D%(R%(A,0),2):GOSUB9:PRINTKK$"  ":SYS34011
1370 PRINTC$"[146]RENN NUMMER      : "D$(R%(A,0),2)
1371 PRINTC$"[146]POSITION IM RENNEN:"D$(R%(A,0),1)
1372 PRINTC$"[146]RENN TYP         : ";:SYS34154
1380 PRINT"[146]";:POKE253,22
1385 IFD%(R%(A,0),0)>0THENPOKE2,1:POKE254,178:SYS35184:PRINT"[158]*CHAMP":GOTO1397
1387 IFD%(R%(A,0),1)=0THENPOKE2,2:POKE254,170:POKE253,20:SYS35184:GOTO1397
1389 IFD%(R%(A,0),9)=0THENPOKE2,0:POKE254,178:SYS35184:PRINT"[156]-MR.X-":GOTO1397
1391 POKE2,3:POKE254,178:SYS35184:PRINT"[158]NEUER "
1397 POKE53275,0
1398 PRINT"[154]";:SYS34536:GOSUB63:POKE53269,0:GOTO1300
1450 PRINTC$"[146]BESITZER         : "P$(D%(R%(A,0),9)):SYS34512
1465 PRINTC$"[146]TRAINER          : "T$(D%(R%(A,0),10))
1470 PRINTC$"[146]FITNESS          : ";:Z=D%(R%(A,0),6):GOSUB9:PRINTKK$"%"
1475 PRINTC$"[146]STARTVERHALTEN   : ";:Z=D%(R%(A,0),7):GOSUB9:PRINTKK$"%"
1480 PRINTC$"[146]BESTE ZEIT       : ";:Z=D%(R%(A,0),4)/100:GOSUB9
1481 IFKK$="99.99"THENKK$="UNRACED"
1482 PRINTKK$
1485 PRINTC$"[146]WERT             : $";:Z=D%(R%(A,0),8)*10:GOSUB9:PRINTKK$
1490 PRINTC$"[146]CUP SIEGE        : ";:Z=D%(R%(A,0),0):GOSUB9:PRINTKK$""
1491 SYS34011:RETURN
1500 FORN=1TOP:P(N,1)=P(N,0):NEXT:FORX=1TO8:IFP(X,2)=0THEN1600
1515 GOSUB25:A=0:FORN=16TO1STEP-1:IFMID$(P$(X),N,1)="."THENA=N
1520 NEXT:B$=P$(X):IFA>1THENB$=LEFT$(P$(X),A-1)
1525 IFP(X,1)<0THENPRINT" DU BIST KREDIT RISIKO "B$"[154]":GOTO1610
1530 PRINT" WOLLEN SIE WETTEN     "B$"?":GOSUB13:IFA$="N"THEN1600
1540 GOSUB25:PRINT" (S)IEG (P)LATZ  (D)REIER    (Z)WEIER  ":A2=0:A3=0
1545 PRINT"[154]";:GOSUB19:PRINT"  DRUECKEN SIE S-P-Z-D FUER WETTTYP   .[146]"
1550 GOSUB6:IFA$<>"S"ANDA$<>"P"ANDA$<>"Z"ANDA$<>"D"THEN1550
1555 TB$=A$:GOSUB25:IFA$="D"THENGOSUB6400:GOSUB25:GOTO1530
1556 IFA$="Z"THENGOSUB6300:GOSUB25:GOTO1530
1557 IFA$="P"THENGOSUB1570:GOSUB25:GOTO1530
1558 IFA$="S"THENGOSUB1560:GOSUB25:GOTO1530
1560 GOSUB1800:PRINT"";:INPUT" WETTHOEHE    ";AM:IFAM>10000ORINT(AM)<>AMTHEN21
1561 IFAM<1THEN21
1562 GOSUB1820:IFP%(1)=ATHENP(X,0)=P(X,0)+((WW*2)*AM)
1569 GOTO1596
1570 GOSUB1800:PRINT"";:INPUT" WETTHOEHE    ";AM:IFAM>10000ORINT(AM)<>AMTHEN21
1571 IFAM<1THEN21
1572 GOSUB1820:IFP%(1)=AORP%(2)=AORP%(3)=ATHENP(X,0)=P(X,0)+((DP(R%(A,1))*2)*AM)
1579 GOTO1596
1580 GOSUB1800:A2=A:GOSUB1800:PRINT"";:INPUT" WETTHOEHE    ";AM
1581 IFAM>10000ORINT(AM)<>AMORAM<1THEN21
1582 GOSUB1820:IFP%(1)<>AANDP%(2)<>ATHEN1596
1583 IFP%(1)<>A2ANDP%(2)<>A2THEN1596
1584 P(X,0)=P(X,0)+((DP(4)*2)*AM):GOTO1596
1590 PRINT" WAEHLE 3 HUNDE IN REIHENFOLGE        .":GOSUB99:GOSUB25
1591 GOSUB1800:A3=A:GOSUB1800:A2=A:GOSUB1800:GOSUB25
1592 INPUT" WETTHOEHE    ";AM:IFAM>10000ORINT(AM)<>AMORAM<1THEN21
1593 IFBT=1THEN6500
1594 GOSUB1820:IFP%(3)<>AORP%(2)<>A2ORP%(1)<>A3THEN1596
1595 P(X,0)=P(X,0)+((DP(5)*2)*AM)
1596 GOSUB25:PRINT" LETZTE WETTE WAR      [154] ";
1597 IFA3<>0THENPRINTCHR$(A3+48)" ";
1598 IFA2<>0THENPRINTCHR$(A2+48)" ";
1599 PRINTCHR$(A+48)" [146]":PRINT" WERT WAR   [154] $";:Z=AM:GOSUB9:GOTO1700
1600 NEXTX:RETURN
1610 SYS34764:GOTO1600
1700 PRINTKK$" [146] OR ";:Z=AM*2:GOSUB9:PRINTKK$" UNITS":SYS34011:GOTO8
1800 PRINT" HUNDENUMMER-WAEHLE          ( 1 - 8 )":GOSUB3:RETURN
1820 P(X,0)=P(X,0)-AM:RETURN
1950 SYS36008:PRINTR$(0):SYS36011:FORN=1TO8:SYS36023
1975 PRINTD$(R%(N,0),1)"[150] "N"[157] "R$(N)" "Z$(N)" ";:NEXTN:SYS36026:RETURN
1999 SYS34536:RETURN
2500 S(1)=2000:S(2)=1000:S(3)=400:S(4)=200
2510 G$=RIGHT$(STR$(R),1):FORN=1TO8:D$(R%(N,0),2)=RIGHT$(D$(R%(N,0),2)+G$,10)
2520 NEXT:FORN=1TO8:G=R%(N,1):G$=RIGHT$(STR$(G),1)
2530 D$(R%(N,0),1)=RIGHT$(D$(R%(N,0),1)+G$,10):NEXT
2540 D%(R%(P%(1),0),1)=D%(R%(P%(1),0),1)+1
2560 D%(R%(P%(2),0),2)=D%(R%(P%(2),0),2)+1
2570 D%(R%(P%(3),0),2)=D%(R%(P%(3),0),2)+1
2580 FORN=1TO8:D%(R%(N,0),3)=D%(R%(N,0),3)+1:NEXT
2590 FORN=1TO8:G=R%(N,0):IFR%(N,4)<D%(G,4)THEND%(G,4)=R%(N,4)
2600 NEXT:IFR<5THENS(1)=1000:S(2)=500:S(3)=200:S(4)=100:S%(R)=R%(P%(8),0)
2610 IFR=1THENFORN=1TO4:N%(5,N)=R%(P%(N),0):NEXT
2620 IFR=2THENFORN=1TO4:N%(5,N+4)=R%(P%(N),0):NEXT
2630 IFR=3THENFORN=1TO4:N%(6,N)=R%(P%(N),0):NEXT
2640 IFR=4THENFORN=1TO4:N%(6,N+4)=R%(P%(N),0):NEXT
2650 IFR=5THENFORN=1TO4:N%(7,N)=R%(P%(N),0):NEXT
2660 IFR=6THENFORN=1TO4:N%(7,N+4)=R%(P%(N),0):NEXT
2665 IFR=7THENS(1)=10000:S(2)=5000:S(3)=2000:S(4)=1000
2670 G=R%(P%(1),4):IFG<TR*100THENTR=G/100
2680 FORN=1TO4:A(N)=R%(P%(N),0):NEXT:FORN=1TO4:A=D%(A(N),8)+(S(N)/10)
2690 IFA>30000THENA=30000
2700 D%(A(N),8)=INT(A):P(D%(A(N),9),0)=P(D%(A(N),9),0)+S(N):NEXTN
2900 RETURN
3000 GOSUB900:POKE53280,0:POKE53281,0:POKE253,40:POKE254,58:POKE2,2:SYS35184
3015 GOSUB40:SYS33873:PRINT" ENDPOSITIONEN   -:":GOSUB60
3017 FORN=1TO8:PRINTY$(N):NEXT:GOSUB60:SYS34536:SYS50176:GOSUB8
3035 GOSUB40:PRINT" DIVIDENDS -:":SYS35425
3037 PRINTY1$:SYS35425:FORK=1TO3:PRINTI$(K):NEXTK:SYS35425:PRINTY2$:PRINTY3$
3040 GOSUB8:GOSUB40
3045 PRINT" DIE BESITZER DER ERSTEN VIER HUNDE   :":SYS35444
3047 FORN=1TO4:PRINTB$(N):NEXT:SYS35444:GOSUB8:GOSUB40
3100 PRINT" GELD VOR UND NACH  DEM RENNEN   -  :":FORN=1TO8:IFP(N,2)=0THEN3150
3110 PRINTC$(N)
3150 NEXTN:GOSUB8:GOTO6250
3500 POKE53280,0:POKE53281,0:POKE253,40:POKE254,68:POKE2,3:SYS35184:GOSUB40
3510 SYS33873:A=D%(S%(R),8)*5:B=D%(S%(R),9):P(B,0)=P(B,0)+A
3512 PRINT" NACHRICHT AN     "P$(B)
3515 PRINT" "D$(S%(R),0)" WURDE VERKAUFT WEIL ":RK=INT(RND(0)*12)
3516 IFRK=0THENPRINT" ER DIE BAHN GEWECHSELT HAT UND ALLE   ":PRINT" BISS.   "
3517 IFRK=1THENPRINT" ER NUTZLOS IST"
3518 IFRK=2THENPRINT" ER DEIN IST."
3519 IFRK=3THENPRINT" ER MIR PECH BRINGT.  "
3520 IFRK=4THENPRINT" ER GEFAEHRLICH IST."
3521 IFRK=5THENPRINT" ER ZU SCHNELL FUER ALLE GEWESEN IST ":PRINT"          ";
3522 IFRK=5THENPRINT"      "
3523 IFRK=6THENPRINT" GRR."
3525 IFRK=7THENPRINT" ER FAST IMMER DER  SCHLECHTESTE WAR. "
3526 IFRK=8THENPRINT" ER MIT SEINEN GEGNER FLIRTET.        "
3527 IFRK=9THENPRINT" ER KRANK IST."
3528 IFRK=10THENPRINT" ER AUF GEGNER WETTET."
3529 IFRK=11THENPRINT" ER FUER DEIN GELD ZUVIE  FRISST,..UND "
3530 IFRK=11THENPRINT" SAEUFT UND DAFUER ZU WENIG POWER     "
3531 IFRK=11THENPRINT" AUF DER BAHN BRINGT !!!               "
3534 PRINT" DER HUND WIRD EINEM FARMER VERKAUFT ":PRINT"FUER $";:Z=A:GOSUB9
3535 PRINTKK$:SYS34011
3550 N=S%(R):GOSUB9990:GOSUB8:GOSUB6250:POKE2,1:SYS35184:GOSUB40:SYS33873
3555 RK=INT(RND(0)*8)+1:IFP(RK,2)=0THEN3555
3560 PRINT" ";P$(RK);".EIN ZUECHTER IST ZU "
3570 PRINT"IHNEN GEKOMMEN.ER WILL EINEN HUND  "
3580 PRINT"IM RENNALTER VERKAUFEN  ."
3590 PRINT" VATERS BESTZEIT    ="(D%(S%(R),5)-100+INT(RND(0)*200))/100
3600 PRINT" MUTTERS BESTZEIT   ="(D%(S%(R),5)-50+INT(RND(0)*200))/100
3610 PRINT" PREIS=$";:Z=D%(S%(R),8)*10:GOSUB9:PRINTKK$:SYS34011
3620 PRINT" WOLLEN SIE DEN HUND KAUFEN  ?":GOSUB13:PRINT"";:IFA$="N"THEN3700
3640 INPUT" RENN-NAME  ";A$:A$=A$+"................":A$=LEFT$(A$,16)
3650 A=0:FORN=1TO32:IFA$=D$(N,0)THENA=1
3660 NEXTN:IFA=1THENPRINT" DIESER NAME IST TRUEBSELIG":GOSUB99:GOSUB40:GOTO3640
3670 D$(S%(R),0)=A$:D%(S%(R),9)=RK:P(RK,0)=P(RK,0)-(D%(S%(R),8)*10)
3680 GOTO3750
3700 GOSUB6250:POKE2,0:SYS35184:GOSUB40:SYS33873
3705 PRINT" DER HUND WURDE   GEKAUFT VON DEM ":PRINT" X-SYNDICATE UND HEIST ";
3710 PRINTD$(S%(R),0):PRINT" IN ERINNERUNG AN DEN VATER.        "
3720 PRINT"     ...RUEHREND NICHT ???":D%(S%(R),6)=75+INT(RND(0)*25):GOSUB8
3750 GOTO6250
4000 CP%=CP%+1:IFR$(P%(1))=CC$THENCC%=CC%+1:GOTO4030
4025 CC%=1:CC$=R$(P%(1))
4030 IFCC%>=MC%THENMC%=CC%:MC$=CC$
4035 D%(R%(P%(1),0),0)=D%(R%(P%(1),0),0)+1
4040 FORN=1TO32:IFD%(N,0)>=CH%THENCH%=D%(N,0):CH$=D$(N,0)
4045 NEXT:FORN=9TO1STEP-1:CW$(N+1)=CW$(N):NEXT:CW$(1)=CC$:RETURN
4500 GOSUB8500:GOSUB6250
4510 POKE53280,0:POKE53281,0:POKE253,40:POKE254,68:POKE2,1:SYS35184:GOSUB40
4520 SYS33873:SYS50176:PRINT" DIE 10 SCHNELLSTEN HUNDE     -:":FORN=1TO10
4530 PRINTRIGHT$(STR$(N),2)" "F$(N);:G=F(N)+.001:G$=LEFT$(STR$(G),6)
4540 PRINTG$:NEXT:GOSUB8:IFCP%<2THEN6250
4543 GOSUB40:IFCP%<10THENGOSUB42:GOTO4555
4545 PRINT" DIE LETZTEN 10 CUPSIEGER    -:":FORN=1TO10
4550 PRINT" CUP ";:A$="  "+STR$(CP%+1-N):PRINTRIGHT$(A$,4)"    "CW$(N):NEXT
4555 GOSUB8
4560 GOSUB40
4570 PRINT" LETZTER CUPSIEGER   "CC$:PRINT" AUFEINANDERFOLGENDE CUPSIEGE   =";
4580 PRINTCC%:PRINT" MEISTE FOLGENDE CUPSIEGE       ="MC%
4590 PRINT" LETZTENS ERREICHT..."MC$:PRINT" "CH$"HAELT DEN REKORD"CH%
4600 PRINT" VON ALLEN   "CP%"CUP SIEGEN.":GOSUB8:GOTO6250
5500 G2=0:SYS33778:SYS34011:SYS33873:SYS50501
5520 FORN=1TO32:IFD%(N,9)<>0THENG2=G2+1:GOSUB5600
5530 NEXTN:IFG2=0THENGOSUB98
5540 GOSUB800:SYS33904:RETURN
5600 B=D%(N,9):IQ$="    "+P$(B)+"WER TRAENIERT  "+D$(N,0)+"......"
5610 IQ$=IQ$+" DRUECKE EINE TASTE( 1-4 ) FUER TRAINER":LS=LEN(IQ$):CT=0
5615 CT=CT+1:A$=MID$(IQ$,CT,1):PRINTA$;:SYS33863:POKE56294,0:GETA$
5620 IFA$="1"ORA$="2"ORA$="3"ORA$="4"THENA=VAL(A$):GOTO5900
5621 FORA=1TO40:NEXTA:K5=0:IFCT<>LSTHEN5615
5622 K5=K5+1:GETA$:IFA$="1"ORA$="2"ORA$="3"ORA$="4"THENA=VAL(A$):GOTO5900
5623 IFK5=50THEN5600
5624 GOTO5622
5625 IQ$="      "+T$(A)+" DANKT DIR FUER DEN NEUEN AUFTRAG                 "
5626 LS=LEN(IQ$):FORT=1TOLS:A$=MID$(IQ$,T,1):PRINTA$;:SYS33863:POKE56294,0
5627 FORX=1TO40:NEXTX,T
5630 IFA=1THEND%(N,6)=INT(D%(N,6)*1.2):D%(N,7)=D%(N,7)+3:P(B,0)=P(B,0)-900
5640 IFA=2THENP(B,0)=P(B,0)-300
5660 IFA=3THEND%(N,6)=INT(D%(N,6)*.9):P(B,0)=P(B,0)-200
5670 IFA=4THEND%(N,6)=INT(D%(N,6)*.5):P(B,0)=P(B,0)-100
5675 D%(N,10)=A
5680 IFD%(N,6)>99THEND%(N,6)=99
5690 IFD%(N,7)>99THEND%(N,7)=99
5700 RETURN
5900 IFG2=1THEN5625
5910 GOTO5630
6000 SYS35616:PRINT" ES SPIELEN JETZT   "P"SPIELER  ":IFP=0THENGOTO4
6020 PRINT" IHRE NAMEN UND GELDSUMMEN SIND:":FORN=1TO8:IFP(N,2)=0THEN6027
6025 PRINTB$(N)
6027 NEXTN:IFP=1THENGOSUB8:GOTO6100
6030 PRINT" WOLLEN SPIELER AUFHOEREN ?     ":GOSUB13:PRINT"";
6040 IFA$="N"THEN6100
6050 PRINT"[145][145][145] SPIELERNUMMER BITTE   ?        "
6055 PRINT"                                       "
6056 PRINT"                                        ":GOSUB3
6060 P(A,2)=0:P=P-1:FORN=1TO32:IFD%(N,9)=ATHEND%(N,9)=0
6070 NEXTN:IFP<2THEN6100
6080 PRINT"[145][145][145][145] HOEREN ANDERE SPIELER AUF?":GOSUB13:PRINT"[145]";
6090 IFA$="Y"THEN6050
6100 IFP=8THEN6200
6110 GOSUB40:PRINT" SIND DORT NEUE SPIELER    ?":GOSUB13:PRINT"";
6120 IFA$="N"THEN6200
6150 PRINT:FORN=8TO1STEP-1:IFP(N,2)=0THENA=N
6160 NEXTN:P(A,0)=20000:P(A,2)=1:INPUT" SPIELER NAME";A$:A$=A$+"..............."
6165 A$=A$+"..":GOSUB40
6170 P=P+1:P$(A)=LEFT$(A$,16):IFP<8THENPRINT" NOCH MEHR SPIELER    ?":GOSUB13
6180 IFP<8THENPRINT"";:GOTO6120
6200 GOSUB40:PRINT"     DER START VON DER WOCHE  "W
6210 FORN=1TO32:F4=INT(RND(0)*4)+1:F8=INT(RND(0)*8)+1:T4=INT(RND(0)*4)+1
6220 T8=INT(RND(0)*8)+1:A=N%(F4,F8):N%(F4,F8)=N%(T4,T8):N%(T4,T8)=A:NEXT
6250 SYS33904:POKE53269,0:RETURN
6300 PRINT" WILLST DU NUR EINEN HUND NENNEN     ?"
6310 PRINT" (DAS KOSTET DICH DAS SIEBENFACHE )   ":GOSUB13:GOSUB25
6320 IFA$="N"THEN1580
6340 GOSUB1800:PRINT"";:INPUT" WETTHOEHE    ";AM
6350 IFAM>10000ORINT(AM)<>AMORAM<1THEN21
6360 AM=AM*7:GOSUB1820:AM=INT(AM/7):IFP%(1)=AORP%(2)=ATHEN6370
6365 A2=22:AM=AM*7:GOTO1596
6370 P(X,0)=P(X,0)+((DP(4)*2)*AM):GOTO6365
6400 PRINT" WOLLEN SIE BELIEBIGE REIHENFOLGE      "
6410 PRINT" (DAS KOSTET DICH DAS SECHSFACHE)     ":GOSUB13:GOSUB25
6420 IFA$="N"THENBT=0:GOTO1590
6430 BT=1:GOTO1591
6500 AM=AM*6:GOSUB1820:AM=INT(AM/6):IFP%(3)<>AANDP%(2)<>AANDP%(1)<>ATHEN6540
6510 IFP%(3)<>A2ANDP%(2)<>A2ANDP%(1)<>A2THEN6540
6520 IFP%(3)<>A3ANDP%(2)<>A3ANDP%(1)<>A3THEN6540
6530 P(X,0)=P(X,0)+((DP(5)*2)*AM)
6540 AM=AM*6:GOTO1596
8500 FORN=1TO32:IFD%(N,4)>=F(10)*100THEN8600
8515 A=1
8516 IFD%(N,4)=F(A)*100ANDD$(N,0)=F$(A)THEN8600
8520 A=A+1:IFA<11THEN8516
8522 A=1
8525 IFD$(N,0)=F$(A)THENG=A:GOTO8532
8530 A=A+1:IFA<11THEN8525
8531 G=0:GOTO8540
8532 IFG=10THEN8540
8535 FORA=GTO9:F(A)=F(A+1):F$(A)=F$(A+1):NEXTA
8540 FORA=10TO1STEP-1:IFD%(N,4)<F(A)*100THENG=A
8545 NEXTA:IFG=10THENF$(10)=D$(N,0):F(10)=D%(N,4)/100:GOTO8600
8550 FORA=9TOGSTEP-1:F(A+1)=F(A):F$(A+1)=F$(A):NEXTA:F$(G)=D$(N,0)
8555 F(G)=D%(N,4)/100
8600 IFPEEK(53252)>150ANDPEEK(53264)>0THENPOKE53269,0
8610 NEXTN:TR=F(1):RETURN
9000 DIMD$(32,2),D%(32,10),R%(32,20),P(10,2),N%(7,8)
9010 OPEN15,8,15:IFPEEK(2)=0THENOPEN8,8,8,"ODATA,S,R":GOSUB1:GOTO9030
9020 OPEN8,8,8,"SDATA,S,R":GOSUB1
9030 INPUT#8,FM$:FORN=1TO10:INPUT#8,F$(N):NEXT:FORN=1TO10:INPUT#8,F(N):NEXT
9040 INPUT#8,MC$,MC%,CC$,CC%,CP%,CH$,CH%:FORN=1TO10:INPUT#8,CW$(N):NEXT
9050 FORN=1TO32:INPUT#8,D$(N,0),D$(N,1),D$(N,2):FORX=0TO10:INPUT#8,D%(N,X)
9051 NEXTX,N:INPUT#8,P:IFP=0THEN9060
9052 FORN=1TO10:INPUT#8,P(N,0),P(N,2),P$(N):NEXTN
9060 CLOSE8:GOSUB1:OPEN8,8,8,"RDATA,S,R":FORN=1TO7:INPUT#8,RN$(N):NEXT
9070 GOSUB1:CLOSE8:CLOSE15
9080 FORN=1TO8:FORA=1TO4:N%(A,N)=N+((A-1)*8):NEXTA,N
9085 FORN=1TO32:D$(N,0)=LEFT$(D$(N,0),16):D$(N,1)=LEFT$(D$(N,1),10)
9090 D$(N,2)=LEFT$(D$(N,2),10):NEXT:FORN=1TO10:F$(N)=LEFT$(F$(N),16)
9095 CW$(N)=LEFT$(CW$(N),16):NEXT:MC$=LEFT$(MC$,16):CC$=LEFT$(CC$,16)
9097 CH$=LEFT$(CH$,16):T$(1)="PETER PAYFORBEST":T$(2)="NEVILLE NOTSOBAD"
9098 T$(3)="NEIL NOTSOGOOD":T$(4)="HARRY HITANDRUN":P$(0)="THE X-SYNDICATE."
9100 TR=F(1):GOSUB800:BP=0:SYS35616:PRINT" REKLAME FUER SCHWACHE WINDHUNDE  ?"
9110 GOSUB13:IFA$="N"THEN100
9120 SYS35616:INPUT" WIEVIEL    (1-4) ";BP:BP=INT(BP+1):IFBP<2ORBP>5THEN9120
9130 GOTO100
9800 OPEN15,8,15:OPEN8,8,8,"@0:SDATA,S,W":GOSUB1:S$=CHR$(13):PRINT#8,FM$
9810 FORN=1TO10:PRINT#8,F$(N):NEXT:FORN=1TO10:PRINT#8,F(N):NEXT
9820 PRINT#8,MC$,S$,MC%,S$,CC$,S$,CC%,S$,CP%,S$,CH$,S$,CH%:FORN=1TO10
9830 PRINT#8,CW$(N):NEXT:FORN=1TO32:PRINT#8,D$(N,0),S$,D$(N,1),S$,D$(N,2)
9838 FORX=0TO10:PRINT#8,D%(N,X):NEXTX,N:PRINT#8,P:R$=CHR$(13):FORN=1TO10
9839 PRINT#8,P(N,0),R$,P(N,2),R$,P$(N):NEXTN
9840 CLOSE8:GOSUB1:CLOSE15:RETURN
9990 D$(N,1)="----------":D$(N,2)=D$(N,1):FORA=0TO3:D%(N,A)=0:NEXT:D%(N,4)=9999
9991 D%(N,5)=INT(RND(0)*251)+2800:D%(N,6)=50:D%(N,7)=INT(RND(0)*100)
9992 IFINT(RND(0)*2)=0THEND%(N,5)=D%(N,5)-2:GOTO9992
9993 X=(3100-D%(N,5))/2
9994 X=X^2:IFX>10000THENX=X+(X-10000):IFX>30000THENX=X+(10*(X-30000))
9999 X=INT(X/10):D%(N,8)=X:D%(N,9)=0:D%(N,10)=2:RETURN